masthead
 

Model 1 using PROC CALIS

The "ram" statement consists of a description of each of the causal paths to be estimated (other methods of model specification are described in the SAS manual). In each line of the ram statement the first number indicates the number of arrowheads for that effect (1 for a direct effect, 2 for a correlation), the second number indicates the recipient of the effect (the variables are referred to in order), and the third number indicates the causal variable. When a name is provided as the fourth entry, the coefficient is estimated; if a number is provided instead, the coefficient is fixed to that value. Any path or correlation not referred to is fixed at zero, and the correlation of a variable with itself is a variance. For more complicated diagrams it may be necessary to explicitly include a
"measurement model" and latent factors - see Hayduk (1987), Loehlin (1987), and Breckler (1990). Although not obvious in this example, implementing path analysis under the assumption of no measurement error actually involves postulating one factor for each measured variable, with factor loadings from each factor to each measured variable of 1.0 (see Hayduk, 1987; Joreskog and Sorbom, 1989).

DATA PATHS(TYPE=COV); /* input the data matrix */
_TYPE_=(COV); /* the data is consists of a variance-covariance matrix */
INPUT _TYPE_ $ _NAME_ $ V1-V6;
LABEL V1='LOGNLFR' V2='NPR' V3='NND' V4='APH'
V5='VPF' V6='PROPFS';
CARDS;
N . 130 . . . . . .
COV V1 0.5711 . . . . .
COV V2 0.0581 0.2421 . . . .
COV V3 0.0564 -.0321 0.2532 . . .
COV V4 0.0320 0.0228 0.0030 0.0292 . .
COV V5 -.00756 0.0048 -.0022 0.0080 0.0048 .
COV V6 -.01368 0.0185 -.0265 0.0055 0.0030 0.0312
;

PROC CALIS CORR /* invoke procedure CALIS, request total effects */
DATA=PATHS TOTEFF;
RAM /* use "ram" method for specification */
1 4 1 BFLRA, /* FLR -> A */ /* specify direct effects, usually with a descriptive comment */
1 4 2 BNPRA, /* NPR -> A */
1 4 3 BNNDA, /* NND -> A */
1 5 1 BFLRP, /* FLR -> P */
1 5 2 BNPRP, /* NPR -> P */
1 5 3 BNNDP, /* NND -> P */
1 5 4 BAP, /* A -> P */
1 6 4 BAF, /* A -> F */
1 6 5 BPF, /* P -> F */
1 6 3 BNNDF, /* NND -> F */
2 2 1 CORFLNL, /* specify correlations */
2 3 1 CORNDFL,
2 3 2 CORNDNP,
2 1 1 VARFLR, /* specify variances */
2 2 2 VARNPR,
2 3 3 VARNND,
2 4 4 VARAPH,
2 5 5 VARVPF,
2 6 6 VARPROP;



Website Terms and Conditions and Privacy Policy
Please send comments or suggestions about this Website to custserv.us@oup.com        
cover